AppleScript InDesign ver. 2


| Indesign CS 2 | | Indesign CS 1 | | Indesign ver. 2 | | Miscellaneous |


Index





— Document Section —
Back to index





New document: width x height
tell application "InDesign 2.0.2"
   set myDocument to make document
   tell document preferences of myDocument
      set page width to "150 mm"
      set page height to "100 mm"
   end tell
end tell

Top of the script | back to index




Open a document
set SourceFileInDesign to "DDOlivier_DOCS:DEV:file.ind"

tell application "InDesign 2.0.2"
   activate
   set myDocument to open file (SourceFileInDesign)
end tell
Top of the script | back to index




Save a document
set theSaveNameINDD to (path to desktop as string) & "test_file.indd"

tell application "InDesign 2.0.2"
   save active document to theSaveNameINDD
   close active document
end tell
Top of the script | back to index




Insert a page
tell application "InDesign 2.0.2"
   tell document 1
      make page at beginning of spread 2
       (* instead of:
      set properties of document preferences to ¬
         {pages per document:4, pages per spread:2}
      *)
   end tell
end tell
Top of the script | back to index




Zoom window
tell application "InDesign 2.0.2"
   set MyWindow to active window
   tell MyWindow
      set zoom percentage to 75
      set bounds to {20, 167, 767, 885}
      set view display setting to typical
   end tell
end tell
Top of the script | back to index




Auto page number
tell application "InDesign 2.0.2"
   tell master spread "A-Master" of document 1
      set myTextFrame to make text frame with properties {geometric bounds:{"6p", "6p", "24p", "24p"}}
      set text of myTextFrame to auto page number
   end tell
end tell
Top of the script | back to index




Index, offset and name of page(s) in a document
tell application "InDesign 2.0.2"
   set myDocument to document 1

   -- Number of pages in the document - 1
   set NumberOfPage_1 to pages per document of document preferences of myDocument

   tell myDocument
      -- Number of pages in the document - 2
      set NumberOfPage_2 to count of pages
      -- in the same idea: number of spread(s) in the document
      set NumberOfSpread to count of spreads

      set myNameList to name of every page
      set myOffsetList to document offset of every page
      set myIndexList to index of every page
   end tell

   -- this is some "reals" applications :
   tell myDocument
      set myName to name of page 2
      set myOffset to document offset of page 2
      set myIndex to index of page 2
   end tell
end tell
Top of the script | back to index




Document preferences Apr 8, 2003
When we created a new document, this one takes the preferences indicated below :

tell application "InDesign 2.0.2"
   set myViewPreferences to view preferences
   tell myViewPreferences
      set horizontal measurement units to points
      set vertical measurement units to points
   end tell
   set myDocPrefs to document preferences
   tell myDocPrefs
      set pages per document to 6
      set page orientation to landscape
      set page height to 612
      set page width to 792
   end tell
   set myMarginPrefs to margin preferences
   tell myMarginPrefs
      set column count to 3
      set column gutter to 12
      set margin top to 36
      set margin bottom to 48
      set margin left to 36
      set margin right to 36
   end tell
   -- set myDocument to make document
end tell 
Top of the script | back to index




The first test Apr 8, 2003
tell application "InDesign 2.0.2"
   activate
   if (count documents) = 0 then
      display dialog "Please, open a document" buttons " OK " default button 1 with icon caution
   else
      set myDocument to active document
      tell myDocument
         --
         -- your code here
         --
      end tell -- myDocument
   end if-- (count documents) = 0
end tell
Top of the script | back to index




Unlock every items May 26, 2003
This script unlock every items:
tell application "InDesign 2.0.2"
   tell all page items of document 1
      set locked to false
   end tell
end tell 

You can use this for: rectangle, oval, graphic line, polygon, text frame (instead of all page items).
Top of the script | back to index




Print multiple ps from layers May 26, 2003
Assuming that you have a printer style named "postscript"
This script make a .ps file on the desktop. One layer = one .ps.

tell application "Finder" to set targetFolder to (desktop of startup disk as text)

tell application "InDesign 2.0.2"
   activate
   try
      set mydoc to active document
      tell mydoc
         set visible of every layer to true

         set myName to (name of mydoc) & "_"
         repeat with i from 1 to count of layers
            set visible of every layer to false
            set visible of layer i to true
            tell print preferences
               set active printer style to "postscript"
               set print file to targetFolder & myName & i & ".ps"
               set printer to postscript file
            end tell
            print without print dialog

         end repeat
         set visible of every layer to true
      end tell
      -- on error ErrorMessage number ErrorNumber
      -- display dialog ("Error : " & return & ErrorMessage & return & ErrorNumber) buttons "OK" default button 1 with icon 0
   end try
end tell

Top of the script | back to index




Make a book of font Nov. 8, 2003
set SizeOfFont to 7
set SizeOfSample to 9

set sampleText to "Quick Brown Dog Thing"
set myBounds to {"20  mm", "20 mm", "220 mm", "120 mm"}

tell application "InDesign 2.0.2"
   activate
   set myFontList to get fonts
   set fontCount to count of myFontList

   set myDocument to make document
   tell page 1 of myDocument
      set myTextFrame to make text frame with properties {geometric bounds:myBounds}
   end tell

   repeat with i from 1 to fontCount
      set thisText to (name of item i of myFontList as string)

      set text contents of insertion point -1 of myTextFrame to (thisText & tab & sampleText & return)
      set LenghtOfThisText to count character of thisText

      if myTextFrame is overflows then
         -- thanks to Dave Saunders for this part (insert a new page and flow text)
         set myFrame to myTextFrame
         tell myDocument
            -- be carrefull: use the name of YOUR master page (I work with a french version)
            set myMaster to object reference of master spread "A-Page type"
            set myNewPage to make page with properties {applied master:myMaster}
         end tell
         set active spread of active window to parent of myNewPage -- show the new page

         tell myNewPage
            set myTextFrame to make text frame with properties {geometric bounds:myBounds}
         end tell
         set next text frame of myFrame to myTextFrame -- text flow
      end if

      tell characters 1 thru LenghtOfThisText of paragraph i of parent story of myTextFrame
         set applied font to item 1 of myFontList
         set point size to SizeOfFont
      end tell
      tell characters (LenghtOfThisText + 1) thru -1 of paragraph i of parent story of myTextFrame
         set applied font to item i of myFontList
         set point size to SizeOfSample
      end tell
   end repeat
end tell
Top of the script | back to index




Some properties Nov. 8, 2003
tell application "InDesign 2.0.2"
   tell document 1
      try
         set MyTextProp to properties of text frame 1
      end try

      try
         set MyLinkProp to properties of link 1
      end try

      try
         set MyPageItemProp1 to properties of page item 1
      end try

      try
         set MyPageProp to properties of page 1
      end try

      try
         tell page 1
            tell item 1
               set MyPageItemProp2 to properties of it
            end tell
         end tell
      end try

      try
         set MyRectangleProp to properties of rectangle 1
      end try

   end tell

   set MySelectionProp to properties of selection
end tell
Top of the script | back to index




Import multi page pdf I think that the idea came from Shane Stanley -- Nov 8, 2003
tell me to set thePDF to choose file with prompt "Choose a pdf" of type {"PDF "}

display dialog "How many pages to import: " default answer 1
set pageCount to text returned of the result

tell application "InDesign 2.0.2"
   activate

   -- Create a new document
   set newDoc to make document

   -- setup dimensions for new document
   set horizontal measurement units of view preferences of newDoc to millimeters
   set vertical measurement units of view preferences of newDoc to millimeters
   set page width of document preferences of newDoc to "210 mm"
   set page height of document preferences of newDoc to "297 mm"

   -- let's see it!
   zoom window 1 of newDoc given fit spread

   -- Add as many pages to the document as there are pages in the PDF
   set pages per document of document preferences of newDoc to (pageCount as number)
   set page orientation of document preferences of newDoc to portrait


   with timeout of 1200 seconds
      -- iterate through every page in the pdf
      repeat with i from 1 to pageCount
         if i mod 2 = 0 then
            -- let's see it!
            set active spread of window 1 to parent of page i of newDoc
         end if

         -- tell InDesign which page of the pdf to place
         set page number of PDF place preferences to i

         -- set the pdf import options
         set PDF crop of PDF place preferences to crop media
         set preserve halftone of PDF place preferences to false
         set transparent background of PDF place preferences to false

         -- and place the file on the right page
         place thePDF on page i of newDoc

      end repeat

   end timeout
   display dialog "Success !!!" buttons "OK" default button 1
end tell


Top of the script | back to index








Address master page item Jan. 7, 2004 -- with Shane Stanley

Put a frame on a master page, and with it selected, open
the Script Label palette from the Window menu. Type in "Current date"
(no quotes) and hit the return key. That labels the frame. Now set your
document to contain 3 pages, or as many as you plan, and run this:


set theDateString to date string of (current date)

tell application "InDesign 2.0.2"
   tell document 1
      set thebox to (master page item 1 of page 1 whose label is "Current date")
      set contents of thebox to theDateString
   end tell
end tell
Top of the script |  back to top






— Page Section —
Back to index



Add a page and flows text Thanks to Dave Saunders
This script adds a page and flows the current text flow into a frame on it.

tell application "InDesign 2.0.1"
   set myStory to parent story of selection
   set myFrame to parent text frame of selection
   set myStart to index of insertion point 1 of selection
   set myPage to name of page 1 of active spread of active window
   tell document 1
      set myMaster to object reference of master spread "C-Lesson Page tall"
      set myNewPage to make page with properties {applied master:myMaster
   end tell
   set active spread of active window to parent of myNewPage
   set myBounds to bounds of myNewPage
   set myMargPrefs to margin preferences of myNewPage
   set item 1 of myBounds to (item 1 of myBounds) + (margin top of myMargPrefs)
   set item 2 of myBounds to (item 2 of myBounds) + (margin left of myMargPrefs)
   set item 3 of myBounds to (item 3 of myBounds) - (margin bottom of myMargPrefs)
   set item 4 of myBounds to (item 4 of myBounds) - (margin right of myMargPrefs)
   tell myNewPage
      set myNewFrame to make text frame with properties {visible bounds:myBounds
   end tell
   set next text frame of myFrame to myNewFrame
end tell
Top of the script | back to index






Get a reference to the page Thanks to Ole Kvern
Question: How do I get an object reference to the page containing a specific page item?

Answer: You use the parent property. For any object (including text objects), the parent property is the item containing the object. For a page item (a rectangle, ellipse, polygon, line, or text frame) that is not inside another page item, the parent is the page; for a text object, the parent is a text frame. Because page items can be nested inside other page items, however, you can't assume that the parent of a page item will always be a page. The following scripts show how to get a reference to the page object containing the selection. They include simple error checking--if nothing is selected, or if you've selected multiple page items, you'll get an error message.


tell application "InDesign 2.0.2"
   set myObject to selection
   try
      if class of myObject = list then
         -- If the class of the selection is list, we know that either nothing is selected 
         -- or multiple object are selected. 
         set myErrorMessage to "Please select a single object and try again."
         error
      end if
      set myParent to parent of myObject
      if class of myParent is not page then
         repeat until class of myParent is page
            set myParent to parent of myParent
         end repeat
      end if
      -- At this point, myParent contains an object reference to the page containing the 
      -- selection. Do with it what you will. 
   on error
      display dialog myErrorMessage
   end try
end tell

Top of the script | back to index






Apply master to page
tell application "InDesign 2.0.1"
   tell document 1
      set the applied master of page 1 of spread 1 to master spread 2
   end tell
end tell
Top of the script | back to index






Show page 4
tell application "InDesign 2.0.2"
   activate
   set active spread of window 1 to parent of page 4 of document 1
end tell
Top of the script | back to index






Section - new
tell application "InDesign 2.0.2"
   set theSection to make section at document 1 with properties {name:"X", page number style:upper roman, page number start:1, page start:page 8 of document 1}
end tell
Top of the script | back to index




Duplicate pages by Olav Kvern -- June 24, 2003
If you're actually trying to duplicate the entire page, try something like this:

set mySourcePageNumber to 1
set numberOfPages to 3
tell application "InDesign 2.0.2"
   tell active document
      repeat numberOfPages times
         set myNewPage to duplicate page mySourcePageNumber
      end repeat
   end tell
end tell
Top of the script | back to index




Duplicate page items by Olav Kvern -- June 24, 2003
If you're trying to duplicate page items from one page to several other pages, try something like this:

set mySourcePageNumber to 1
set myTargetPages to {2, 3, 4, 5}
tell application "InDesign 2.0.2"
   tell active document
      set ruler origin of view preferences to page origin
      set zero point to {0, 0}
      repeat with myCounter from 1 to (count myTargetPages)
         set mySourcePage to page mySourcePageNumber
         try
            set myTargetPage to page (item myCounter of myTargetPages)
         on error
            set myTargetPage to make page at end
         end try
         repeat with myPageItemCounter from (count page items of mySourcePage) to 1 by -1
            set myClone to duplicate page item myPageItemCounter of mySourcePage
            copy geometric bounds of myClone to myBounds
            tell myClone
               move to myTargetPage
               set geometric bounds to myBounds
            end tell
         end repeat
      end repeat
   end tell
end tell
Top of the script | back to index




Pages : Index-Offset-Name Nov 8, 2003
 
tell application "InDesign 2.0.2"
   tell active document
      set NumberOfPage to pages per document of document preferences
      set myNameList to name of every page
      set myOffsetList to document offset of every page
      set myIndexList to index of every page
   end tell
end tell
Top of the script | back to index




Move Page Order by Sean Dellis -- May 31, 2004
Send by Sean Dellis (indesign@dadgummit.org).
Description:
This script is designed to move a page to a different page. Simply make a selection on your current page and specify the destination. It was designed for working on a document without facing pages, but should also work with facing pages.


tell application "InDesign 2.0.2"
   activate
   tell document 1
      set currentSelection to selection
      if (count of currentSelection) < 1 then
         display dialog "Please make a selection on the page you want to move." default button ["OK"] with icon stop
      else
         set activePage to name of parent of item 1 of selection
         display dialog "Where do you want to move the current page?" default answer "" with icon note
         if (text returned of result) = "" then
            display dialog "Please enter a page number." default button ["OK"] with icon stop
         else
            try
               set destinationPage to (text returned of result) as number
               set numberPages to count of pages
               if numberPages < destinationPage then
                  display dialog "There are not that many pages in your document." default button ["OK"] with icon stop
               else if 1 = destinationPage then
                  move page activePage to before page (destinationPage as number
               else if numberPages = destinationPage then
                  move page activePage to after page (destinationPage as number
               else
                  move page activePage to before page (destinationPage + 1 as number
               end if
            on error
               display dialog "You must enter a number." default button ["OK"] with icon stop
            end try
         end if
      end if
   end tell
end tell
Top of the script | back to index






— Frame Section —
Back to index





Create a frame : how to use "bounds" ?
The bounds of an object is a list of 4 values, in this order: the top, the left, the bottom and the right.
So, to create a frame with these bounds in InDesign:
x: 12 mm w: 186 mm
y: 29 mm h: 256 mm
you must use:
top left bottom right
y x (y + height) (x + width)
29 12 (29+256) (12+186)
Here, the construction:
tell application "InDesign 2.0.2"
   tell document 1
      tell page 1
         make text frame with properties {geometric bounds:¬
            {"29 mm", "12 mm", "285 mm", "198 mm"}}
      end tell
   end tell
end tell 
Top of this explanation | back to top




Change text frame to rectangle
tell application "InDesign 2.0.1"
   tell document 1
      make new text frame at end of page 1 with properties {geometric bounds:{"0 mm", "0 mm", "20 mm", "20mm"}}
      set x to id of text frame 1
      set properties of page item id x to {content type:graphic}
      properties of rectangle id x
   end tell
end tell
Top of the script | back to index




Remove frame from story by Ole Kvern
-- RemoveFrameFromStory
-- This InDesign 2.x script removes the selected text frame
-- and the text it contains from its parent story. The frame
-- and its content will appear in the same position as it
-- originally occupied--it just won't be threaded to the story
-- anymore. This is similar to deleting and then power pasting
-- a text block in PageMaker. You can select multiple text frames.
tell application "InDesign 2.0.2"
   set mySelection to selection
   if (count mySelection) is not equal to 0 then
      repeat with myCounter from (count mySelection) to 1 by -1
         if class of item myCounter of mySelection is text frame then
            set myTextFrame to item myCounter of mySelection
            tell myTextFrame
               duplicate
               delete characters 1 through -1 of myTextFrame
               delete
            end tell
         end if
      end repeat
   end if
end tell
Top of the script | back to index




Delete every unused text frame thanks to Shane Stanley
(* loop through all frames
   IF this frame
      is a text frame AND
      ((contents is empty) OR (contents = carriage return)) AND
      fill color is none AND
      stroke color is none AND
      text wrap is none  
   THEN delete this frame.
*)

property idCR : "
" -- a  carriage return

tell application "InDesign 2.0.2"
   set allFrames to all page items of active document

   repeat with aFrame in allFrames
      if (class of aFrame is text frame) and ¬
         (contents of parent story of aFrame is in {idCR, ""}) and ¬
         (name of fill color of aFrame is "None") and ¬
         (name of stroke color of aFrame is "None") and ¬
         (text wrap of aFrame is none) ¬
            then delete aFrame
   end repeat

end tell
Top of the script | back to index




Make a text frame with properties Mar 17, 2003
(*
This script shows 2 methods to make a text frame with some properties.
The first one use the reference "tell text frame …" to set some options.
Be carrefull: the order of these options is important.
Try with the line "set the rotation angle to 90" at the end of the "tell text frame" !

The second one use a direct syntax: make text frame […] with properties […]
*)

set TheHeader to "This is the first test"

tell application "InDesign 2.0.2"
   activate
   set myDoc to active document
   tell myDoc
      tell page 1
         set TheHeaderFrame to make text frame

         tell TheHeaderFrame -- tell text frame…
            set the rotation angle to 90 -- try with this line after the line "set the label to [...]"
            set the geometric bounds to {"15.0 mm", "-5.0 mm", "69.0 mm", "8.0 mm"}
            set contents to TheHeader
            set the fill color to swatch "Black" of myDoc
            set the fill tint to 10
            set the stroke color to swatch "None" of myDoc
            set the stroke tint to 100
            set the stroke weight to 0
            set the label to "TheHeaderFrame"
         end tell

         tell text frame preferences of TheHeaderFrame
            set text column count to 2
            set text column gutter to "5 mm"
            set vertical justification to bottom
         end tell
      end tell
   end tell
end tell

-- just for debugging
delay 2

set TheHeader to "This is the second test"

tell application "InDesign 2.0.2"
   set myDoc to active document
   tell page 1 of myDoc
      set TheHeaderFrame to make text frame with properties ¬
         {geometric bounds:{"15.0 mm", "-5.0 mm", "69.0 mm", "8.0 mm"} ¬
            , text contents:TheHeader ¬
            , fill color:swatch "Black" of myDoc, fill tint:10 ¬
            , stroke color:swatch "None" of myDoc, stroke tint:100, stroke weight:0 ¬
            , rotation angle:90 ¬
            , label:"TheHeaderFrame"}

      set text column count of text frame preferences of TheHeaderFrame to 2
      set text column gutter of text frame preferences of TheHeaderFrame to "5 mm"
      set vertical justification of text frame preferences of TheHeaderFrame to bottom
   end tell
end tell
Top of the script | back to index




Center selection by Shane Stanley -- May 26, 2003
--   Centering selected objects on a page.

tell application "InDesign 2.0.2"
   set {a, b, c, d} to bounds of page 1 of document 1
   set theSel to selection
   if (count of theSel) > 1 then
      make group at parent of item 1 of theSel with data theSel
      set {w, x, y, z} to geometric bounds of result
      undo document 1 -- undo the grouping
   else
      set {w, x, y, z} to geometric bounds of item 1 of theSel
   end if
   move selection by {(d / 2 - (x + z) / 2), (c / 2 - (w + y) / 2)}
end tell
Top of the script | back to index




Get bounds of last text frame May 26, 2003
tell application "InDesign 2.0.2"
   tell active document
      tell last page
         tell last text frame
            set myBounds to geometric bounds of it
         end tell
      end tell
   end tell
end tell
Top of the script | back to index




Ignore wrap May 26, 2003
tell application "InDesign 2.0.2"
   tell document 1
      tell every text frame
         tell text frame preferences
            set ignore wrap to true
         end tell
      end tell
   end tell
end tell
Top of the script | back to index


Frame: 2 columns and add 33 mm Nov 25, 2003
Add 33 mm to the widht of the text frame and change to 2 columns

tell application "InDesign 2.0.2"
   set mySel to {}
   try
      set mySel to item 1 of selection
   end try
   tell mySel
      if class of mySel is not text frame then
         display dialog ("please, select a text frame")
      else
         set {a, b, c, d} to geometric bounds
         set geometric bounds to {a, b, c, (d + 33)}
         set text column count of text frame preferences to 2
      end if
   end tell
end tell
Top of the script | back to index




Align objects Dec 3, 2003
set ListOfActions to {"1 Center selection vertically", "2 Center selection horizontally", "3 Selection in the center", ¬
   "4 Align to the top & left", "5 Align to the top", "6 Align to the top & right", ¬
   "7 Align to the left", "8 Align to the right", "9 Align to the bottom & left", ¬
   "10 Align to the bottom", "11 Align to the bottom & right", "12 Align to the top & center", ¬
   "13 Align to the left-center", "14 Align to the right", "15 Align to the bottom & center"}

tell application "InDesign 2.0.2"
   activate
   if (count documents) = 0 then
      display dialog "Please, open a document." buttons " Ooops " default button 1 with icon caution
   else
      set myDocument to active document

      tell myDocument
         set {a, b, PageHeight, PageWidth} to bounds of page 1 of document 1
         set mySelection to selection
         if (count of mySelection) = 0 then
            display dialog "Please, select an item or" & return & "a group of items" buttons " OK " default button 1 with icon caution
         else
            if (count of mySelection) > 1 then
               make group at parent of item 1 of mySelection with data mySelection
               set {PointY, PointX, PointRight, PointBottom} to geometric bounds of result
               undo document 1 -- undo the grouping
            else
               set {PointY, PointX, PointRight, PointBottom} to geometric bounds of item 1 of mySelection
            end if

            set ChoiceAction to (choose from list ListOfActions with prompt "Choose an action") as string

            if ChoiceAction = "1 Center selection vertically" then
               move selection by {(PageWidth / 2 - (PointX + PointBottom) / 2), 0}
            else if ChoiceAction = "2 Center selection horizontally" then
               move selection by {0, (PageHeight / 2 - (PointY + PointRight) / 2)}
            else if ChoiceAction = "3 Selection in the center" then
               move selection by {(PageWidth / 2 - (PointX + PointBottom) / 2), (PageHeight / 2 - (PointY + PointRight) / 2)}
            else if ChoiceAction = "4 Align to the top & left" then
               move selection by {-PointX, -PointY}
            else if ChoiceAction = "5 Align to the top" then
               move selection by {0, -PointY}
            else if ChoiceAction = "6 Align to the top & right" then
               move selection by {PageWidth - PointBottom, -PointY}
            else if ChoiceAction = "7 Align to the left" then
               move selection by {-PointX, 0}
            else if ChoiceAction = "8 Align to the right" then
               move selection by {PageWidth - PointBottom, 0}
            else if ChoiceAction = "9 Align to the bottom & left" then
               move selection by {-PointX, PageHeight - PointRight}
            else if ChoiceAction = "10 Align to the bottom" then
               move selection by {0, PageHeight - PointRight}
            else if ChoiceAction = "11 Align to the bottom & right" then
               move selection by {PageWidth - PointBottom, PageHeight - PointRight}
            else if ChoiceAction = "12 Align to the top & center" then
               move selection by {(PageWidth / 2 - (PointX + PointBottom) / 2), -PointY}
            else if ChoiceAction = "13 Align to the left-center" then
               move selection by {-PointX, (PageHeight / 2 - (PointY + PointRight) / 2)}
            else if ChoiceAction = "14 Align to the right" then
               move selection by {PageWidth - PointBottom, (PageHeight / 2 - (PointY + PointRight) / 2)}
            else if ChoiceAction = "15 Align to the bottom & center" then
               move selection by {(PageWidth / 2 - (PointX + PointBottom) / 2), PageHeight - PointRight}
            end if
         end if -- if (count of mySelection) = 0
      end tell -- tell myDocument
   end if --    if (count documents) = 0
end tell
Top of the script | back to index






— Image Section —
Back to index





Place an image
set myNameFile to "swap:5099703229929.eps"

tell application "InDesign 2.0.2"
   activate
   set myDoc to active document

   tell page 1 of myDoc
      set myEANRectangle to make rectangle >with properties {geometric bounds:{43, 158, 60, 198}}

      try
         place alias (myNameFile) on myEANRectangle

         set myImage to page item 1 of myEANRectangle
         set myImageBounds to geometric bounds of myImage
         -- you can use the direct approach:
         -- set myImageBounds to geometric bounds of page item 1 of myEANRectangle

         set item 1 of myImageBounds to (item 1 of myImageBounds) + 2
         set item 2 of myImageBounds to (item 2 of myImageBounds) + 3
         set item 3 of myImageBounds to (item 3 of myImageBounds) + 2
         set item 4 of myImageBounds to (item 4 of myImageBounds) + 3

         set geometric bounds of myImage to myImageBounds
      on error
         -- do your stuff
      end try
   end tell
end tell
Top of the script | back to index




Real bounds of an image with Kari Puikkonen
set myUseVisible to true
tell application "InDesign 2.0.2"
   tell document 1
      tell view preferences
         set oldPrefs to properties
         set properties to {horizontal measurement units:centimeters, vertical measurement units:centimeters}
      end tell
      set oldDelims to AppleScript's text item delimiters
      set AppleScript's text item delimiters to {":"}
      repeat with i from 1 to count of links

         set thePath to (file path of link text i) as text
         set thePic to parent of link i
         set theHolder to parent of thePic
         set theParent to parent of theHolder
         set myBounds to visible bounds of thePic

         set MyImageBounds to geometric bounds of thePic

         set theWidth to (item 4 of MyImageBounds) - (item 2 of MyImageBounds)
         set theHeight to (item 3 of MyImageBounds) - (item 1 of MyImageBounds)

         -- in case it's in a group:
         repeat while class of theParent is not page
            set theParent to parent of theParent
         end repeat
         set {a, b, c, d} to visible bounds of theHolder
         set newFrame to make new text frame at theParent with properties ¬
            {visible bounds:{a, b, a + 1, b + 100} ¬
               , contents:((text item -1 of thePath) & "  " & (theWidth) & "  " & (theHeight) & "  ") ¬
               , fill color:color "Paper", label:"Pic label"}
         set properties of text frame preferences of newFrame to {ignore wrap:true, inset spacing:0, first baseline offset:cap height, vertical justification:center}
         set properties of parent story of newFrame to {applied font:"Times", font style:"Roman", point size:7, leading:10, justification:left, left indent:0.2, hyphenation:false}
         set theRight to horizontal offset of character -1 of newFrame
         set visible bounds of newFrame to {a, b, a + 1, theRight + 0.1}
      end repeat
      set AppleScript's text item delimiters to oldDelims
      tell view preferences
         set properties to oldPrefs
      end tell
   end tell
end tell
Top of the script | back to index




Identify images with text by Jan Suhr (made with some help from Shane Stanley)
It will search a document for its placed images and put a small
textbox under each image so that you can see on the page which image it is.
It is useful for people who wants to find images used in a production
for later usage. The imagename boxes will be on its own layer so it
can be turned off.

Be carrefull: this version doesn't work if image(s) is/are on a Master Page.
An other note: this script treats all the links: XLS, PDF, EPS...

tell application "InDesign 2.0.2"
   set myDocument to active document
   set myTextInfoLayerName to "Text Info"
    -- If the measurement units of the active document are not points, set the
   -- measurement units to points.
   if horizontal measurement units of view preferences of myDocument is not millimeters or ¬
      vertical measurement units of view preferences of myDocument is not millimeters then
      set myOldViewPreferences to properties of view preferences of myDocument
      set horizontal measurement units of view preferences of myDocument to millimeters
      set vertical measurement units of view preferences of myDocument to millimeters
      set myResetUnits to true
   else
      set myResetUnits to false
   end if

   tell myDocument
      set Info to make paragraph style with properties ¬
         {name:"Image name info", applied font:"Helvetica", font style:"Regular", point size:11, justification:right}
      try
         -- Get the layer on which to place the crop marks.
         set myLayer to layer myTextInfoLayerName of myDocument
      on error
         -- Create the layer if it didn't already exist.
         tell myDocument
            set myLayer to make layer
            set name of myLayer to myTextInfoLayerName
         end tell
      end try

      set IDLinks to links whose status is normal
      -- Search document for linked images
      repeat with myCounter from 1 to (count IDLinks)

         set LinkName to name of item myCounter of IDLinks as string
         set theImage to parent of item myCounter of IDLinks
         set theFrame to parent of theImage
         set ImgPos to geometric bounds of theFrame
         repeat
            set theClass to class of parent of theFrame
            if theClass = spread then
               set theSpread to parent of theFrame
               exit repeat
            else
               set theFrame to parent of theFrame
            end if
         end repeat

         set myY1 to (item 1 of ImgPos)
         set myX1 to (item 2 of ImgPos)
         set myY2 to (item 3 of ImgPos)
         set myX2 to (item 4 of ImgPos)
         -- Calculates the textbox size
         set myX2a to (myX2 - 60)
         set myY2a to (myY2 + 4)

         set ImgTxtFrame to make text frame at theSpread
         set geometric bounds of ImgTxtFrame to {myY2, myX2a, myY2a, myX2}

         set applied paragraph style of insertion point -1 of ImgTxtFrame to Info
         set contents of insertion point -1 of ImgTxtFrame to (LinkName as string)
      end repeat
   end tell

   -- Resets the units back from millimetersto the old setting
   if myResetUnits is true then
      tell view preferences of myDocument to set properties to myOldViewPreferences
   end if
end tell

Top of the script | back to index




Image proportional maxi Apr 9, 2003 -- Note from Pete Johnston: Dec 9, 2003
This script "put" all selected images to proportional + 0,5 %. You can select some object (frame, line, ...) without inconveniance.

tell application "InDesign 2.0.2"
   tell document 1
      set theSelection to selection

      repeat with anItem in theSelection
         set theTarget to anItem
         set theClass to class of theTarget
         if theClass is in {EPS, PDF} then -- if the image is selected by direct tools
            set theTarget to parent of anItem
         end if

         if page item 1 of theTarget exists then
            tell theTarget
               fit given content to frame
               set horScale to (horizontal scale of page item 1) + 0.5 -- add 0.5 %
               set vertScale to (vertical scale of page item 1) + 0.5 -- add 0.5 %

               -- Pete Johnston, proposes :
               set horScale to (horizontal scale of page item 1) * 1.005 -- add 0.5 % 
               set vertScale to (vertical scale of page item 1) * 1.005 -- add 0.5 % 
               -- This will scale the image to 0.5% larger relative to the frame size, rather than relative to the original image size.


               if horScale is greater than vertScale then
                  set vertical scale of page item 1 to horScale
                  set horizontal scale of page item 1 to horScale
               else
                  set horizontal scale of page item 1 to vertScale
                  set vertical scale of page item 1 to vertScale
               end if
               fit given center content
            end tell
         end if
      end repeat
   end tell
end tell
Top of the script | back to index




Reveal image in the finder May 23, 2003
set theFilePathOfImage to ""

tell application "InDesign 2.0.2"
   try
      set theSelection to item 1 of theSelection
      set theClass to class of theSelection
      if theClass is in {EPS, PDF} then -- if the image is selected by direct tools
         set theSelection to parent of theSelection
         set theClass to class of theSelection
      end if
      -- try to get the file path of the item:
      set theFilePathOfImage to file path of item link of page item 1 of theSelection
   on error
      -- many cases: a) the selection is {} ; b) the selection is a text or a text frame ; c) the selection is a line ; d) ...
      display dialog "Choose an image" buttons "OK" default button 1 with icon 1
   end try
end tell

if theFilePathOfImage is not "" then
   tell application "Finder"
      activate
      reveal the theFilePathOfImage
   end tell
end if
Top of the script | back to index




Place images in order by Olav Kvern -- June 24, 2003
Placing all images from a specified folder into a new InDesign document.
Page order can be either "back to front" or "front to back".
Set myReverseOrder to false to get standard Roman layout direction.


set myReverseOrder to true
-- Set page height, page width
set myPageWidth to 115
set myPageHeight to 180

-- Display a "Choose Folder" dialog box.
set myFolder to choose folder with prompt "Select the folder containing the files you want to place."

tell application "Finder"
   set myFiles to files of myFolder
   set myNumberOfPages to (count myFiles)
    -- The sort method is not yet available for the OSX Finder.
   -- Make sure that the files in the folder
   -- are sorted in the order in which you want them to appear.
   -- Uncomment this line if you're using OS 9.
   -- set myFiles to sort files of myFolder by name
end tell

tell application "InDesign 2.0.2"
   set myDocument to active document

   if myReverseOrder is true then
      set myPageNumber to myNumberOfPages
      set myPageIncrement to -1
   else
      set myPageNumber to 1
      set myPageIncrement to 1
   end if

   -- make a layer whose name is Image layer
   tell myDocument
      try
         set ImageLayer to layer "Image layer" of myDocument
      on error
         set ImageLayer to make layer with properties {visible:true, locked:false, name:"Image layer"}
      end try
   end tell

   repeat with myCounter from 1 to myNumberOfPages
      set myFileName to item myCounter of myFiles as string
      set myPage to page myPageNumber of myDocument
      tell myPage
         -- place the image on the "Image layer"
         set myRectangle to make rectangle >with properties {geometric bounds:{0, 0, myPageHeight, myPageWidth}, item layer:layer "Image layer"}
         tell myRectangle
            place myFileName
         end tell
         fit myRectangle given content to frame
         fit myRectangle given proportionally
      end tell
      set myPageNumber to myPageNumber + myPageIncrement
   end repeat
end tell
Top of the script | back to index






— Text Section —
Back to index





Make a text frame
set TheHeader to "This is the Header"
tell application "InDesign 2.0.1"
   tell document 1
      tell page 2
         set TheHeaderFrame to make text frame with properties {geometric bounds:{"15.0", "-5.0", "69.0", "8.0"}, rotation angle:90, text contents:TheHeader}
         set vertical justification of text frame preferences of TheHeaderFrame to bottom
      end tell
   end tell
end tell
Top of the script | back to index




What's in the selection? Thanks to Dave Saunders
What's in the selection?
This script doesn't do anything, but can be used as the basis for any that acts on the selection.
tell application "InDesign 2.0.2"
   activate
   set myTextObjects to {insertion point, character, word, line, paragraph, text column, text, story}
   if (count documents) > 0 then
      set mySelection to selection
      if (count mySelection) > 0 then
         if class of item 1 of mySelection is in myTextObjects then
            display dialog "The selection is a text selection."
         else if class of item 1 of mySelection is guide then
            display dialog "The selection is a guide or guides."
         else
            display dialog "The selection contains a page item or page items."
         end if
      else
         display dialog "Nothing is selected."
      end if
   else
      display dialog "Please open a document, select an item or items, and try again."
   end if
end tell
Top of the script | back to index




Change point size Thanks to Dave Saunders
tell application "InDesign 2.0.1"
   tell document 1
      tell story 1
         -- set point size of characters #5 through characters #-1 to 16
         set point size of characters 5 through -1 to 16
      end tell
   end tell
end tell
Top of the script | back to index




Character style from selection
Create a complete character style based on the selected text
tell application "InDesign 2.0.1"
   set myTextObjects to {insertion point, character, word, line, paragraph, text style range, text column, text, story}
   set mySelection to selection
   if class of item 1 of mySelection is in myTextObjects and mySelection is not equal to {} then
      if class of item 1 of mySelection is insertion point then
         set myCharacter to item 1 of mySelection
      else
         set myCharacter to object reference of character 1 of item 1 of mySelection
      end if
      set myCharacter to object reference of item 1 of selection
      tell active document
         set myCharacterStyle to make character style
         set applied font of myCharacterStyle to applied font of myCharacter
         set font style of myCharacterStyle to font style of myCharacter
         set point size of myCharacterStyle to point size of myCharacter
         if leading of myCharacter is "auto" then
            set leading of myCharacterStyle to -1
         else
            set leading of myCharacterStyle to leading of myCharacter
         end if
         set kerning method of myCharacterStyle to kerning method of myCharacter
         if kerning method of myCharacterStyle = none then
            set kerning value of myCharacterStyle to kerning value of myCharacter
         end if
         set tracking of myCharacterStyle to tracking of myCharacter
         -- set case of myCharacterStyle to case of myCharacter
         set position of myCharacterStyle to position of myCharacter
         set underline of myCharacterStyle to underline of myCharacter
         set strike thru of myCharacterStyle to strike thru of myCharacter
         set ligatures of myCharacterStyle to ligatures of myCharacter
         set figure style of myCharacterStyle to figure style of myCharacter
         set no break of myCharacterStyle to no break of myCharacter
         set horizontal scale of myCharacterStyle to horizontal scale of myCharacter
         set vertical scale of myCharacterStyle to vertical scale of myCharacter
         set baseline shift of myCharacterStyle to baseline shift of myCharacter
         set skew of myCharacterStyle to skew of myCharacter
         set applied language of myCharacterStyle to applied language of myCharacter
         set fill color of myCharacterStyle to fill color of myCharacter
         set stroke color of myCharacterStyle to stroke color of myCharacter
         set fill tint of myCharacterStyle to fill tint of myCharacter
         set stroke tint of myCharacterStyle to stroke tint of myCharacter
         set stroke weight of myCharacterStyle to stroke weight of myCharacter
         set overprint stroke of myCharacterStyle to overprint stroke of myCharacter
         set overprint fill of myCharacterStyle to overprint fill of myCharacter
         set otf ordinal of myCharacterStyle to otf ordinal of myCharacter
         set otf fraction of myCharacterStyle to otf fraction of myCharacter
         set otf discretionary ligature of myCharacterStyle to otf discretionary ligature of myCharacter
         set otf titling of myCharacterStyle to otf titling of myCharacter
         set otf contextual alternate of myCharacterStyle to otf contextual alternate of myCharacter
         set otf swash of myCharacterStyle to otf swash of myCharacter
         set otf stylistic alternate of myCharacterStyle to otf stylistic alternate of myCharacter
      end tell
   end if
end tell
Top of the script | back to index




Text frame-gutter & column
Each text frame has its own set of text frame settings that you access by using the "text frame preferences" property.

tell application "InDesign 2.0.2"
   set mySpread to active spread of active window
   tell mySpread
      set myTextFrame to make text frame
      tell myTextFrame
         set geometric bounds to {"10", "10", "287", "200"}
         -- set text contents to "This is some example text"
         tell text frame preferences
            set text column count to 2
            set text column gutter to 0
         end tell
      end tell
   end tell
end tell
Top of the script | back to index




Insert text
tell document 1 of application "InDesign 2.0.1"
   tell page 1
      set theMainText to make text frame with properties {geometric bounds:{10, 10, 50, 50}}
   end tell
   set text contents of insertion point -1 of theMainText to ("This is a test" & return)
end tell
Top of the script | back to index




Place a text Thanks to Dave Saunders
set tempfilepath to (choose file) as text
set MyHead to "blah-blah-blah"
tell application "InDesign 2.0.2"
   tell document 1
      try
         set myYellow to color "Yellow"
      on error
         set myYellow to make color with properties {name:"Yellow", color space:cmyk, color value:{0, 0, 100, 0}}
      end try
      if MyHead is not "" then
         set myFrame to make text frame at page 1 with properties {geometric bounds:{3, 3, 33, 33}, fill color:myYellow}
      end if
      place tempfilepath on myFrame without showing options
   end tell
end tell
When you want to import a text file, tell the text object to place the file;
When you want to enter a string into a text object, tell the text object to set its contents to the string.

Telling a text frame to set its contents to a string of tagged text will result in the tagged text appearing--literally, tags and all--in the frame,
because the tags have to go through the import (place) mechanism to be interpreted.
If you simply set the contents of a frame to some string, you're not using the import filter.
Top of the script | back to index




Put a bullet in front of each selected paragraph
tell application "InDesign 2.0.2"
   activate
   set myTextObjects to {insertion point, character, word, line, text style range, paragraph, text column, text, story}
   set mySelection to selection
   if (count mySelection) > 0 and class of item 1 of mySelection is in myTextObjects then
      set myText to item 1 of mySelection
      tell myText
         set left indent of it to "2.5"
         set first line indent of it to "-2.5"
      end tell
      set myText to object reference of item 1 of selection
      set myParas to object reference of every paragraph of selection
      set n to count of myParas
      set MyBullet to "•" & tab
      repeat with x from n to 1 by -1
         set contents of insertion point 1 of paragraph x of myText to MyBullet
      end repeat
   else
      display dialog "Please select a range of paragraphs and try again." buttons "OK" default button 1 with icon 2
   end if
end tell
Top of the script | back to index




Rule of paragraph
tell application "InDesign 2.0.2"
   tell paragraph 1 of selection
      set rule above to true
      set rule above color to swatch "Black" of document 1
      set rule above line weight to 0.4
      set rule above offset to "0p1.5"
      set rule above right indent to "0p306"
   end tell
end tell
Top of the script | back to index




Select the last character
Assuming that "myFrame" has a reference to a frame.

tell application "InDesign 2.0.2"
   set theX to horizontal offset of character -1 of myFrame
   set theY to baseline of character -1 of myFrame
end tell

Top of the script | back to index




Counter of words, characters and paragraphs
tell application "InDesign 2.0.2"
   activate
   if (count documents) = 0 then
      display dialog "You must open a document !" buttons " OK " default button 1 with icon caution
   else
      set mySelection to selection
      if (count mySelection) = 0 or (class of selection is not text) then
         display dialog "You must select text" & return & "before run this script" buttons " OK " default button 1 with icon caution
      else
         set myParagraphs to (count of paragraphs of selection)
         set myWords to (count of words of selection)
         set myCharacters to (count of characters of selection)
         display dialog ¬
            "Number of word           : " & myWords & return & ¬
            "Number of characters   : " & myCharacters & return & ¬
            "Number de paragraphs : " & myParagraphs & return & return buttons " OK " default button 1 with icon note
      end if
   end if
end tell
Top of the script | back to index




Sort paragraphs By Olav Kvern -- Mar 12, 2003
Sorts the selected paragraphs alphabetically.

set myErrorString to "Please select a range of paragraphs and try again."
tell application "InDesign 2.0.2"
   set myTextObjects to {insertion point, character, word, line, text style range, paragraph, text column, text, story}
   set mySelection to selection
   if (count mySelection) > 0 and class of item 1 of mySelection is in myTextObjects then
      set myText to item 1 of mySelection
      set myNumberOfParagraphs to (count paragraphs of myText)
      if myNumberOfParagraphs > 1 then
         set myStory to parent of myText
         set myStart to my myGetParagraphIndex(index of paragraph 1 of myText, myStory)
         set myEnd to my myGetParagraphIndex(index of paragraph -1 of myText, myStory)
         -- If the last paragraph is at the end of the story, add a return to the end of the paragraph.
         set myLastCharacter to character -1 of paragraph -1 of myText
         if myLastCharacter is not return then
            set contents of insertion point -1 of paragraph -1 of myText to return
         end if
         my mySortParagraphs(myStart, myEnd, myStory)
         -- Deselect the sorted paragraphs.
         tell application "InDesign 2.0.2"
            select nothing
         end tell
      else
         my myErrorMessage(myErrorString)
      end if
   else
      my myErrorMessage(myErrorString)
   end if
end tell

on myErrorMessage(myErrorString)
   tell application "InDesign 2.0.2"
      activate
      display dialog myErrorString
   end tell
end myErrorMessage

on myGetParagraphIndex(myIndex, myStory)
   tell application "InDesign 2.0.2"
      repeat with myCounter from 1 to (count paragraphs of myStory)
         set myStart to index of paragraph myCounter of myStory
         if myStart is equal to myIndex then
            return myCounter
         end if
      end repeat
   end tell
end myGetParagraphIndex

-- Bubble sort for sorting paragraphs.
on mySortParagraphs(myStart, myEnd, myStory)
   tell application "InDesign 2.0.2"
      repeat
         set myItemMoved to false
         set myCounter to myStart
         repeat while myCounter is less than myEnd
            if paragraph (myCounter) of myStory > paragraph (myCounter + 1) of myStory then
               tell paragraph myCounter of myStory
                  move to after paragraph (myCounter + 1) of myStory
               end tell
               set myItemMoved to true
            end if
            set myCounter to myCounter + 1
         end repeat
         set myCounter to myEnd
         repeat while myCounter is greater than myStart
            if paragraph myCounter of myStory < paragraph (myCounter - 1) of myStory then
               tell paragraph myCounter of myStory
                  move to before paragraph (myCounter - 1) of myStory
               end tell
               set myItemMoved to true
            end if
            set myCounter to myCounter - 1
         end repeat
         if myItemMoved is false then
            exit repeat
         end if
      end repeat
   end tell
end mySortParagraphs
Top of the script | back to index






Change paragraph settings Apr 7, 2003
tell application "InDesign 2.0.2"
   set aDocument to active document
   tell aDocument
      -- you can use this construction...
      set myTextReference1 to object reference of paragraph 1 of story 1
      set applied font of myTextReference1 to "Helvetica"
      set font style of myTextReference1 to "Bold"

      -- … or this construction …
      set myTextReference2 to object reference of paragraph 2 of story 1
      tell myTextReference2
         set left indent to "3"
         set first line indent to "-3"
         set right indent to "5"
         set point size to 30
         set leading to 45

         set fill color to swatch "Red" of aDocument
         set fill tint to 50

         set justification to left

         set rule below left indent to "5"
         set rule below right indent to "5"
         set rule below to true
         set rule below line weight to 10
         set rule below color to swatch "Black" of aDocument

         set space after to 5
         set space before to 10
      end tell

      -- … you can also use this construction:
      set myTextReference3 to object reference of paragraph 3 of story 1
      set properties of myTextReference3 to {horizontal scale:90 ¬
         , align to baseline:true ¬
         , drop cap lines:3 ¬
         , drop cap characters:10}
   end tell
end tell
Top of the script | back to index




Tab stop By Olav Kvern -- May 15, 2003
Olav notes: Just a quick note on tab stop creation--
The method used above to set the position, leader, and alignment of the tab stops works fine.
But if, for whatever reason, you end up creating tab stops and setting their attributes in separate steps, beware!
When you create a new tab stop, InDesign puts it at 0 on the tab ruler. Since tab stop object references are assigned from left to right on the ruler,
this means that the tab stop is tab stop 1. If, however, you move the tab stop by changing its alignment, its object reference will change when
you move it to the right of any other tab stop on the tab ruler.
This means that subsequent property assignments will be applied to the wrong tab stop, as demonstrated in the following script:

This script will assign the leader/alignment to the wrong tab stop.

tell application "InDesign 2.0.2"
   tell active document
      tell every paragraph of story 1
         set myTabStop to make tab stop
         tell myTabStop
            set position to 12
            set alignment to left
            set leader to "."
         end tell
         set myTabStop to make tab stop
         tell myTabStop
            set position to 24
            set alignment to right
            set leader to "--"
         end tell
      end tell
   end tell
end tell
-- To avoid this problem, set the tab stops other properties *before* setting its position, as shown in the example below:
-- This script will assign the leader/alignment correctly.
tell application "InDesign 2.0.2"
   tell active document
      tell every paragraph of story 1
         set myTabStop to make tab stop
         tell myTabStop
            set alignment to left
            set leader to "."
            set position to 12
         end tell
         set myTabStop to make tab stop
         tell myTabStop
            set alignment to right
            set leader to "--"
            set position to 24
         end tell
      end tell
   end tell
end tell

-- Again, it's best to use "with properties"--I just thought I should mention this.
tell application "InDesign 2.0.2"
   set myStory to parent story of selection
   tell every paragraph of myStory
      make tab stop with properties {position:24, alignment:right, leader:"--"}
   end tell
end tell
Top of the script | back to index




Change to italic June 24, 2003
Change to italic some words in a list.

set ListOfWord to {"Tennis", "Bridge", "Golf", "Squash"}

tell application "InDesign 2.0.2"
   activate
   set find preferences to nothing
   set change preferences to nothing

   tell document 1
      repeat with anItem in ListOfWord
         search document 1 with find attributes {find text:anItem} with change attributes {applied font:font "ITC Usherwood   Book Italic"}
      end repeat
   end tell

   set find preferences to nothing
   set change preferences to nothing
end tell
beep 2
Top of the script | back to index




Find chained text frame by Dave Saunders -- June 24, 2003
Find InDesign stories with more than 1 text frame

tell application "InDesign 2.0.2"
   tell document 1
      set myLongStories to object reference of every story whose text frame -1 is not equal to text frame 1
   end tell
end tell
Top of the script | back to index




Split selected frames by Olav Kvern -- June 24, 2003
Splits a story into separate text frames.

This script splits the selected story into unthreaded text frames.
Each text frame contains the text and formatting it contained when it was part of
the threaded story. Any overset text included in the original story will be deleted.

tell application "InDesign 2.0.2"
   set myTextObjects to {insertion point, character, word, line, text style range, text, paragraph, text column, text frame}
   set MySelection to selection
   if (count MySelection) > 0 then
      repeat with myCounter from 1 to (count MySelection)
         if class of item myCounter of MySelection is in myTextObjects then
            if class of item myCounter of MySelection is text frame then
               set myTextFrame to item myCounter of MySelection
            else
               set myTextFrame to parent of item myCounter of MySelection
            end if
            duplicate myTextFrame
            set label of myTextFrame to "delete_this_frame"
         end if
      end repeat
      tell active document
         set myTextFrames to text frames whose label is "delete_this_frame"
         repeat with myCounter from (count myTextFrames) to 1 by -1
            set myTextFrame to item myCounter of myTextFrames
            set contents of myTextFrame to ""
            tell myTextFrame to delete
         end repeat
      end tell
   end if
end tell
Top of the script | back to index




Paste as plain text by Rich McCormick-Carroll of Capps Digital Development Group -- June 26, 2003
This script works in OS X and in OS 9.x, but only
if you have text selected or have an insertion point
active in a text frame.

set myString to the clipboard as string
tell application "InDesign 2.0.2"
   set mySelection to selection
   if (count mySelection) > 0 then
      set mySelection to item 1 of mySelection
      set text contents of mySelection to myString
   end if
end tell
Top of the script | back to index




InDKerning by Rich McCormick-Carroll of Capps Digital Development Group -- June 26, 2003
Assumes you have a pair selected or a text insertion point between characters.
If you have a text selection that spans more than two characters,
only the first two characters will be used.

tell application "InDesign 2.0.2"
   try
      if class of item 1 of selection is text or class of item 1 of selection is insertion point then
         if class of item 1 of selection is text then
            set myCount to (count characters of item 1 of selection)
            if myCount is 2 then
               set myText to object reference of item 1 of selection
            else if myCount is 1 then
               set myIndex to index of character 1 of item 1 of selection
               set myText to object reference of characters myIndex through (myIndex + 1) of parent story of item 1 of selection
            else
               set myText to object reference of characters 1 through 2 of item 1 of selection
               display dialog "You have " & myCount & " characters selected. This script will only use the first two characters selected."
            end if
         else if class of item 1 of selection is insertion point then
            set myIndex to index of item 1 of selection
            set myText to object reference of characters (myIndex - 1) through myIndex of parent story of item 1 of selection
         end if
         set kerningValue to kerning value of character 1 of myText
         set charContents to contents of myText
         set charFontStyle to font style of myText
         set CharFontSize to point size of myText
         set charFont to applied font of myText
         set find preferences to nothing
         set change preferences to nothing
         set myFoundItems to search document 1 for charContents with find attributes {applied font:charFont, point size:CharFontSize, font style:charFontStyle} with case sensitive
         repeat with myFoundItem in myFoundItems
            -- Apply kerning to the *first* character in each found pair
            set properties of character 1 of myFoundItem to {kerning value:kerningValue}
         end repeat
         set myItemCount to count of items in myFoundItems
         display dialog "All done. " & myItemCount & " instances replaced."
      else
         error
      end if
   on error
      activate
      display dialog "Please select a character pair or insertion point and try again."
   end try
end tell
Top of the script | back to index




Chain 2 text frames Nov 8, 2003
set myText to "Lorem et nosto conse vel utat.
Lorem acidunt augiamc mmodio od mincin essequi esectet augiamconsed dolor acil eumsandre consed ex exer illandrer alit lum ad dolenim in henis nonulputem qui bla feummy nulla feum iurerat, sequi blandre velit, qui blaorerat.
Lore facincip ent la facincil el delis acipsum ipit wisl iliquatum inciduisi.
Lor aliquatuer sisl ullam alit aliquat.
Duisissi blaor alit lumsan utpat. Duipit wis ero odipis nos num elendigna con enibh eumsan utpatet dolobortio od doloreraesed eniscipsustisim zzriustin eu facin eu faciliquat non esto consequ mconsenit augiam, ver at, sisim ip estrud tismod eum alit lutpat, veliquisi blaore eros num quipsuscin henis nostie tat prat. Duis aliquis equat, vel dignim esed tie cor ilis er iureet wisim velenis er sumsandre dignis nis am velisis ad euismodipit lum do dolutet nit, suscilis dunt dionsed et iurero odolobortio elesequam dolumsandre vel ullan vulluptat, verosto exeratetum velesse uamet vullam quisim volore magna feugiam digna feugiam volor augiam, quat alisit irit prat."

tell application "InDesign 2.0.2"
   activate
   set myDoc to make document

   tell myDoc
      set myTextFrame1 to make text frame
      set myTextFrame2 to make text frame

      tell myTextFrame1
         set geometric bounds to {15, 15, 115, 65}
         set contents to myText
      end tell

      set geometric bounds of myTextFrame2 to {15, 70, 115, 120}

      set next text frame of myTextFrame1 to myTextFrame2
   end tell
end tell
Top of the script | back to index




Change every language Nov 8, 2003
tell application "InDesign 2.0.2"
   activate
   if (count documents) = 0 then
      display dialog "Please, open a document before run this script" buttons " OK " default button 1 with icon caution
   else
      set listOfLanguage to name of every language

      copy (choose from list listOfLanguage with prompt "Choose the language for every text") to dialog1

      if dialog1 is not false then
         set myLanguage to language (item 1 of dialog1)

         set applied language of ¬
            every text of ¬
            every paragraph of ¬
            every text frame of ¬
            every page of document 1 to myLanguage
      end if
      beep 2
   end if
end tell
Top of the script | back to index




Horizontal offset Nov 8, 2003
This script put a guide at the end of every paragraph of this text.

set myParagraphs to {"This is a short test", ¬
   "Lore te duiscip endiam essectem veleseq ", ¬
   "iscil ipisisl ero od min hent et accummolore", ¬
   "magna atum veliquipis do deliquis nim qui bla feugiam", ¬
   "sit at alit, quat am, cor ilis am, qui tin heniam zzrilla facil dolortinibh ent ut eniam, si.", ¬
   "Lore ero odolobor inim verostrud dio consequat, consequisi."}

tell application "InDesign 2.0.2"
   activate
   set myDoc to active document

   tell myDoc
      set mainFrame to make text frame with properties {geometric bounds:{10, 10, 100, 100}}
      repeat with aLine in myParagraphs
         set text contents of insertion point -1 of mainFrame to (return & aLine)
         tell mainFrame
            set myHorizontalOffset to horizontal offset of last character of last paragraph
            get properties of last paragraph
         end tell
      end repeat

      set myHorizontalOffset to {}
      set mainFrame to text frame 1 of page 1
      tell mainFrame
         repeat with i from 1 to count of paragraph of mainFrame
            set end of myHorizontalOffset to horizontal offset of last character of paragraph i
         end repeat
      end tell
      repeat with aGuide in myHorizontalOffset
         set myGuide to make guide with properties {orientation:vertical, location:aGuide}
      end repeat
   end tell
end tell
Top of the script | back to index




Change horizontal scale of text Feb 5, 2004
This script "shrink-to-fit" text in a text frame by reducing the horizontal scaling.
I reduce the horizontal scaling 1 % by 1 %, but you can change to reduce 0.5 % by 0.5 %, or ...

Assume that you have a text frame selected

tell application "InDesign 2.0.2"
   activate
   tell document 1
      set theFrame to item 1 of selection
      set theStory to parent story of theFrame

      -- overflow  ??? (myOver is a boolean)
      set myOver to overflows of theFrame

      -- get the horizontal scale of the story
      set myScale to horizontal scale of theStory as integer

      repeat until myOver is false
         set myScale to myScale - 1 -- set myScale to myScale - 0.5

         -- reduce the horizontal scale
         set horizontal scale of theStory to myScale

         -- overflow  ???
         set myOver to overflows of theFrame
      end repeat
   end tell
end tell
Top of the script |  back to top






— Table Section —
Back to index





Table from selection Thanks to Dave Saunders, with help from Ole
tell application "InDesign 2.0.2"
   set mySelection to selection
   set myItem to object reference of item 1 of mySelection
   if class of myItem is character then
      tell myItem
         set myTable to make table
      end tell
   else
      -- error; do whatever you need to do
   end if
end tell
Top of the script | back to index




Move cell 1 to cell 2 Thanks to Dave Saunders
tell application "InDesign 2.0.1"
   set theCell to parent of item 1 of selection
   set theTable to parent of theCell
   move text of cell 1 of row 3 of theTable to after insertion point -1 of cell 1 of row 2 of theTable
end tell

Top of the script | back to index




Format a table Thanks to Dave Saunders
Assuming myTable has the table you want to operate on and myStyle1 and myColor1 have the character style and color for the first row and myStyle2 myColor2 have the character style and color for the rest of the cells:

tell application "InDesign 2.0.2"
   tell myTable
      tell cells of row 1
         set applied character style of text 1 to myStyle1
         set fill color to myColor1
      end tell
      tell cells from cell 1 of row 2 to cell -1
         set applied character style of text 1 to myStyle2
         set fill color to myColor2
      end tell
   end tell
end tell
Top of the script | back to index




Merge cells Thanks to Dave Saunders -- Nov 8, 2003
Select two (and only two) columns of a table.
This script merge the first column of the selection with the second column of the selection.

tell application "InDesign 2.0.2"
   activate
   set myDoc to active document
   tell myDoc
      set theCells to cells of selection
      set cellCount to count of theCells
      set theStart to index of cell 1 of selection
      set i to 1
      set n to cellCount / 2
      repeat with i from 1 to cellCount by 2
         merge item i of theCells with item (i + 1) of theCells
      end repeat
   end tell
end tell
beep 2
Top of the script | back to index




Mesure the width of some columns Nov. 8, 2003
column 1 = 80 mm
column 2 = 10 mm
column 3 to (-3) = 40 / count of column
column (-1) = 20 mm
column (-2) = 20 mm


tell application "InDesign 2.0.2"
   activate
   set myDoc to active document
   tell myDoc
      set mySelection to item 1 of selection
      set myColumns to count of columns of mySelection
      set myWidthOfColumn to 40 / (myColumns - 4)
      set properties of column 1 of mySelection to {width:80}
      set properties of column 2 of mySelection to {width:10}
      set properties of columns 3 thru (myColumns - 2) of mySelection to {width:myWidthOfColumn}
      set properties of columns (myColumns - 1) thru (myColumns) of mySelection to {width:20}
   end tell
end tell
Top of the script | back to index




Set the height of the cell to 10 Nov. 8, 2003
tell application "InDesign 2.0.2"
   set myDoc to active document

   tell myDoc
      try
         tell selection
            set height to "10"
         end tell
      end try
   end tell

end tell
Top of the script | back to index




Format a table with many properties Nov. 8, 2003
This script format a table of minimum 4 columns
2 colors: White and Blue
4 styles: "Lines", "Center lines", "Price Futura Roman", "Price Futura Bold"

It takes 4 secondes for a table of 7 columns and 40 lines.


tell application "InDesign 2.0.2"
   activate
   set mydoc to active document
   tell mydoc
      set WhiteColor to color "White"
      set BlueColor to color "Blue"

      set styleNormal to paragraph style "Lines"
      set styleNormalCenter to paragraph style "Center lines"
      set styleRomanPrice to paragraph style "Price Futura Roman"
      set styleBoldPrice to paragraph style "Price Futura Bold"

      set mySelection to item 1 of selection

      set NumberOfColumns to count column of mySelection

      -- Styles
      set applied paragraph style of parent story of column 1 of mySelection to styleNormal

      set column2ThruMinus3 to columns 2 thru -3 of mySelection
      repeat with aColumn in column2ThruMinus3
         set applied paragraph style of parent story of aColumn to styleNormalCenter
      end repeat

      set applied paragraph style of parent story of column -2 of mySelection to styleRomanPrice
      set applied paragraph style of parent story of column -1 of mySelection to styleBoldPrice

      -- Stroke
      set properties of mySelection to {fill color:WhiteColor ¬
         , inner column stroke weight:0.25, inner row stroke weight:0.25, top edge stroke weight:0.25, bottom edge stroke weight:0.25, left edge stroke weight:0, right edge stroke weight:0}
      set properties of mySelection to {inner column stroke color:BlueColor, inner row stroke color:BlueColor ¬
         , left edge stroke color:color BlueColor, right edge stroke color:color BlueColor ¬
         , bottom edge stroke color:BlueColor, top edge stroke color:BlueColor}

      -- Height, inset
      set properties of mySelection to {height:2.8, vertical justification:center, left inset:0, right inset:0, top inset:0, bottom inset:0}

      -- Width, inset
      set properties of ((columns 2 thru -3) of mySelection) to {width:(80 / NumberOfColumns), fill color:WhiteColor}
      set properties of ((columns -1 thru -2) of mySelection) to {width:20, right inset:4, fill color:BlueColor, fill tint:20}
   end tell
end tell
Top of the script | back to index






— Search & Replace —
Back to index





Search and replace
set theSearchString to "Blablabla"
set theReplaceString to "This is my Replace string"

tell application "InDesign 2.0.2"
   set myTextObjects to {character, word, line, text style range, ¬
      text, paragraph, text column, text frame, cell, column, row, table}
   -- store find/change preferences
   set myOldFindAttributes to properties of find preferences
   set myOldChangeAttributes to properties of change preferences
   -- clear find/change preferences
   set find preferences to nothing
   set change preferences to nothing
   set mySelection to selection
   if (count mySelection) > 0 then
      repeat with myCounter from 1 to (count mySelection)
         set myItem to object reference of item myCounter of mySelection
         if class of myItem is in myTextObjects then
            tell myItem
               search for theSearchString replacing with theReplaceString
            end tell
         end if
      end repeat
   end if
   -- restore find/change preferences
   set properties of find preferences to myOldFindAttributes
   set properties of change preferences to myOldChangeAttributes
end tell

Top of the script | back to index




Delete every paragraphs whose contents = return Thanks to Steve Nichols
tell application "InDesign 2.0.1"
   activate
   tell document 1
      delete (every paragraph of every story whose contents = return)
   end tell
end tell
Top of the script | back to index




Change every "y" to red Thanks to Peter Boctor
tell application "InDesign 2.0.1"
   tell document 1
      set myColor to swatch "Red"
      tell text frame 1
         search for "y" with change attributes {fill color:myColor}
      end tell
   end tell
end tell
Top of the script | back to index




Search & replace all the number and apply the character style "Number" Thanks to Kari Puikkonen & Shane Stanley
tell application "InDesign 2.0.2"
   set find preferences to nothing
   set change preferences to nothing
   tell document 1
      set theStyle to character style "Number"
      search document 1 with find attributes {find text:"^9"} with change attributes {applied character style:theStyle}
   end tell
end tell
Top of the script | back to index




Search dot and replace by period in cell(s) Mar 20, 2003
-- This script try to find "." and replace by "," in cell(s) of a table

set theSearchString to "."
set theReplaceString to ","

tell application "InDesign 2.0.2"
   set mySelection to selection

   if (count mySelection) = 1 then
      set myClass to class of item 1 of selection

      if myClass is insertion point then
         set myClass to class of parent of item 1 of selection
         if myClass = cell then
            select parent of item 1 of selection -- extend the selection on the entire cell
         end if
      end if

      if myClass is cell then
         -- store find/change preferences
         set myOldFindAttributes to properties of find preferences
         set myOldChangeAttributes to properties of change preferences
         -- clear find/change preferences
         set find preferences to nothing
         set change preferences to nothing

         set mySelection to cells of selection
         set cellCount to count of mySelection
         repeat with myCounter from 1 to cellCount
            tell item myCounter of mySelection
               try
                  search for theSearchString replacing with theReplaceString
               end try
            end tell
         end repeat

         -- restore find/change preferences
         set properties of find preferences to myOldFindAttributes
         set properties of change preferences to myOldChangeAttributes
         beep 2
      else
         -- myClass is not "cell"... tell what's in the selection
         display dialog ¬
            "You must select at least " & return ¬
            & "ONE CELL of a table " & return ¬
            & "before run this script," & return ¬
            & "not a “" & myClass & "”." buttons "OK" default button 1 with icon caution
      end if
   else
      -- selection = 0 or more than 1 object
      display dialog ¬
         "You must select at least " & return ¬
         & "ONE CELL of a table " & return ¬
         & "before run this script." buttons "OK" default button 1 with icon caution
   end if
end tell
Top of the script | back to index



You can make a search (and replace) in (in alphabetical order):
  • application
  • cell
  • character
  • column
  • document
  • line
  • paragraph
  • row
  • story
  • table
  • text
  • text column
  • text style range
  • word
You can use also wild cards:
example: Search with wild cards in the fourth text frame of page 1 (see below)

Search with wildcards Apr 7, 2003
tell application "InDesign 2.0.2"
   set aDoc to active document
   tell aDoc
      get properties of text frame 4 of page 1
      tell text frame 4 of page 1
         set searchList to search for "in^?er^?ion" -- insertion or inversion for example
      end tell
   end tell

   -- you can use this construction:
   set searchList to search text frame 4 of page 1 of active document for "in^?er^?ion"

end tell
Top of the script | back to index




Search with attributes Apr 7, 2003
tell application "InDesign 2.0.2"
   set change preferences to nothing
   set find preferences to nothing

   set myDoc to active document
   tell myDoc
      search with find attributes {underline:true} ¬
         with change attributes {fill color:swatch "Red" of myDoc, underline:false}
   end tell

   set change preferences to nothing
   set find preferences to nothing
end tell

Go to "find preferences" and "change preferences",
in the InDesign dictionnary, to see other options like :
"align to baseline", "point size", "leading", "vertical scale", …
Top of the script | back to index






— Color Section —
Back to index



Color - make new
tell application "InDesign 2.0.1"
   tell document 1
      set myNewColor to make color with properties {color value:{100, 100, 0, 0}, name:"Blue 100 100"}
      set myNewPantone to make color with properties {color value:{"PANTONE 2735 CV"}}
      -- set myColor to color "PANTONE 2735 CV"
   end tell
end tell
Top of the script | back to index




Gradient - create
Create a new gradient swatch.

tell application "InDesign 2.0.2"
   activate
   tell active document
      set myColor1 to make color with properties {color model:process, color space:cmyk, color value:{80, 30, 40, 0}, name:"Color_a"}
      set myColor2 to make color with properties {color model:process, color space:cmyk, color value:{100, 100, 50, 0}, name:"Color_b"}

      set myGradient to make gradient

      tell myGradient
         set gradient type to linear
         set stopcolor of gradient stop 1 to myColor1
         set stopcolor of gradient stop 2 to myColor2
         set name to "My gradient"
      end tell
   end tell
end tell
Top of the script | back to index




Search for fill color = none with Shane Stanley
tell application "InDesign 2.0.2"
   set theTextFrames to object reference of every text frame of active document
   repeat with myTextFrame in theTextFrames
      set myFillColor to the properties of fill color of myTextFrame
      if the name of myFillColor is "None" then
         beep
      end if

      if the name of the properties of fill color of myTextFrame is "None" then
         beep
      end if

   end repeat
end tell
Top of the script | back to index




Use a color
tell document 1 of application "InDesign 2.0.2"
   set BlackColor to swatch "Black"
   set fill color of text frame 1 of page 1 to BlackColor
end tell
Olav write: "[…] the reason that your color reference didn't work is that you were referring to a color belonging to the application, rather than a color belonging to a document. The application colors/swatches can never be applied to page items--their only purpose is to set the default set of colors for new documents you create."
Top of the script | back to index




Delete swatch by Ole Kvern
Another possibility is to use the delete command, assuming no imported objects use the color:
tell application "InDesign 2.0.2"
   tell document 1
      delete swatch "PANTONE 315 CV" replacing with swatch "PANTONE 315 CVU"
   end tell
end tell

Top of the script | back to index




Text color Nov. 8, 2003
This script make a text frame on the first page of the active document, put a text in it and fill color of this text to Red.

tell application "InDesign 2.0.2"
   activate
   set myDoc to active document
   tell myDoc
      tell page 1
         set aFrame to make text frame
         tell aFrame -- tell text frame…
            set the geometric bounds to {"10  mm", "10  mm", "60  mm", "60  mm"}
            set contents to "blablabla"
            tell paragraph 1 of it -- it = aFrame = text frame
               set properties to {fill color:swatch "Red" of myDoc}
            end tell
         end tell
      end tell
   end tell
end tell
Top of the script | back to index


Search for colored objects Nov. 8, 2003
tell application "InDesign 2.0.2"
   activate
   if (count documents) = 0 then
      display dialog "Please, open a document before run this script" buttons " OK " default button 1 with icon caution
   else
      set myDoc to active document

      set myWindow to active window

      tell myDoc
         set swatcheslist to name of swatches

         copy (choose from list of swatcheslist with prompt "Choose a color") to dlog1

         if dlog1 is not false then
            set ChoosedColor to swatch (item 1 of dlog1)

            -- Fill color   
            set ListOfColoredObjects to every page item whose fill color is ChoosedColor
            set NumberOfColoredObject to count of ListOfColoredObjects

            -- Stroke color   
            set ListOfStrokedObjects to every page item whose stroke color is ChoosedColor
         end if
      end tell

      set ListOfAllObject to ListOfColoredObjects & ListOfStrokedObjects

      if (count of ListOfAllObject) = 0 then
         copy (display dialog "No object have " & item 1 of dlog1 & " as color" buttons {"Cancel"} default button 1) to dlog2
      else
         set i to 1
         repeat until i > (count of ListOfAllObject)
            set myObj to object reference of (item i of ListOfAllObject)
            set active spread of myWindow to parent of parent of myObj
            select myObj
            tell myWindow
               zoom given fit page
            end tell

            if i < NumberOfColoredObject then
               set myMessage to "Fill Color " & i as string
            else
               set myMessage to "Stroke Color " & i as string
            end if

            if (i = 1) and (i = (count of ListOfAllObject)) then
               copy (display dialog myMessage & " - first & last object" buttons {"Cancel"} default button 1) to dlog2
            else
               if i = 1 then
                  copy (display dialog myMessage & " - first object - Continue ?" buttons {"Cancel", "Next"} default button 2) to dlog2
               else
                  if i = (count of ListOfAllObject) then
                     copy (display dialog myMessage & " - Last object" buttons {"Previous", "OK"} default button 2) to dlog2
                  else
                     copy (display dialog myMessage & " - Continue ?" buttons {"Cancel", "Previous", "Next"} default button 3) to dlog2
                  end if
               end if
            end if
            if button returned of dlog2 = "Cancel" then
               return -128
            else
               if button returned of dlog2 = "Previous" then
                  set i to i - 1 -- previous object
               else
                  set i to i + 1 -- next object
               end if
            end if
         end repeat
      end if
   end if
end tell
Top of the script | back to index


Converting to cmyk Nov. 8, 2003
tell application "InDesign 2.0.2"
   tell active document
      set theListOfColors to (every color where color space is not cmyk)
      set properties of every color of document 1 to {color model:process, color space:cmyk}
   end tell
end tell
Top of the script | back to index


Valid HTML 4.01!